front-integrations/terraform/locals.tf

locals {
  account_id   = "011934824531"
  boundary_arn = "arn:aws:iam::${local.account_id}:policy/seahaven-lambda-execution-boundary-front-integrations"

  schedule_state = var.schedules_enabled ? "ENABLED" : "DISABLED"

  sla_monitor_env = {
    FRONT_SECRET_NAME   = var.front_api_token_secret_arn
    SLACK_SECRET_NAME   = var.slack_bot_token_secret_arn
    SLACK_ALERT_CHANNEL = var.slack_alert_channel
    ADAM_EMAIL          = var.adam_email
    TABLE_NAME          = aws_dynamodb_table.alerts.name
    ACK_SLA_MINUTES     = tostring(var.ack_sla_minutes)
    ACTION_SLA_MINUTES  = tostring(var.action_sla_minutes)
    MONITOR_INBOXES     = var.monitor_inboxes
    START_DATE          = var.sla_monitor_start_date
  }

  user_sync_env = {
    GOOGLE_SECRET_NAME = var.google_service_account_secret_arn
    FRONT_SECRET_NAME  = var.front_api_token_secret_arn
    GOOGLE_ADMIN_EMAIL = var.google_admin_email
    GOOGLE_OUS         = var.google_org_units
  }

  sla_monitor_secrets_policy_json = jsonencode({
    Version = "2012-10-17"
    Statement = [
      {
        Effect = "Allow"
        Action = ["secretsmanager:GetSecretValue"]
        Resource = [
          var.front_api_token_secret_arn,
          var.slack_bot_token_secret_arn,
        ]
      }
    ]
  })

  user_sync_secrets_policy_json = jsonencode({
    Version = "2012-10-17"
    Statement = [
      {
        Effect = "Allow"
        Action = ["secretsmanager:GetSecretValue"]
        Resource = [
          var.google_service_account_secret_arn,
          var.front_api_token_secret_arn,
        ]
      }
    ]
  })

  sla_monitor_ddb_policy_json = jsonencode({
    Version = "2012-10-17"
    Statement = [
      {
        Effect = "Allow"
        Action = [
          "dynamodb:GetItem",
          "dynamodb:PutItem",
          "dynamodb:UpdateItem",
          "dynamodb:DeleteItem",
          "dynamodb:Query",
          "dynamodb:Scan",
          "dynamodb:BatchGetItem",
          "dynamodb:BatchWriteItem",
          "dynamodb:DescribeTable",
        ]
        Resource = [
          aws_dynamodb_table.alerts.arn,
          "${aws_dynamodb_table.alerts.arn}/index/*",
        ]
      }
    ]
  })
}